blob: 327e44ad6393c5845dd4fb3cbfe6689ad0a2d7e7 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
|
# Maintainer: Yigit Sever <yigit at yigitsever dot com>
# Contributor: Caltlgin Stsodaat <contact@fossdaily.xyz>
pkgname='dnsx'
pkgver=1.1.5
pkgrel=1
pkgdesc='Fast and multi-purpose DNS toolkit'
arch=('x86_64')
url='https://github.com/projectdiscovery/dnsx'
license=('MIT')
makedepends=('go')
provides=("${pkgname}")
source=("${pkgname}-${pkgver}.tar.gz::${url}/archive/v${pkgver}.tar.gz")
sha256sums=('e55aff16ff72d7408108fd754c7d67baa6936792fba87a362f12c6871bf26ad4')
prepare() {
export GOPATH="${srcdir}/gopath"
go clean -modcache
}
build() {
export CGO_CPPFLAGS="${CPPFLAGS}"
export CGO_CFLAGS="${CFLAGS}"
export CGO_CXXFLAGS="${CXXFLAGS}"
export CGO_LDFLAGS="${LDFLAGS}"
export GOFLAGS="-buildmode=pie -trimpath -ldflags=-linkmode=external -mod=readonly -modcacherw"
cd "${pkgname}-${pkgver}/cmd/${pkgname}"
go build -v -o "${pkgname}" .
}
package() {
cd "${pkgname}-${pkgver}"
install -Dvm755 "cmd/${pkgname}/${pkgname}" -t "${pkgdir}/usr/bin"
install -Dvm644 'README.md' -t "${pkgdir}/usr/share/doc/${pkgname}"
install -Dvm644 'LICENSE.md' "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
|
