1 files changed, 31 insertions, 0 deletions

diff --git a/tidy-viewer/PKGBUILD b/tidy-viewer/PKGBUILD
new file mode 100644
index 0000000..fd4ff96
--- /dev/null
+++ b/tidy-viewer/PKGBUILD
@@ -0,0 +1,31 @@
+# Maintainer: Yigit Sever <yigit at yigitsever dot com>
+
+pkgname=tidy-viewer
+_pkgname=tv
+pkgver=0.0.22
+pkgrel=1
+pkgdesc="CLI csv pretty printer that uses column styling"
+arch=('x86_64' 'aarch64')
+url="https://github.com/alexhallam/tv"
+license=('Unlicense')
+makedepends=('cargo')
+source=("${_pkgname}-${pkgver}.tar.gz::${url}/archive/${pkgver}.tar.gz")
+sha256sums=('b6f3edf58314b2f69a40d63a032684b1b30406eb03ab1926493b83e92da08884')
+
+prepare() {
+  cd "$_pkgname-$pkgver"
+  cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
+}
+
+build() {
+  cd "$_pkgname-$pkgver"
+  export RUSTUP_TOOLCHAIN=stable
+  export CARGO_TARGET_DIR=target
+  cargo build --frozen --release
+}
+
+package() {
+  cd "$_pkgname-$pkgver"
+  install -Dm0755 -t "$pkgdir/usr/bin/" "target/release/$pkgname"
+  install -Dm644 "$srcdir/$_pkgname-$pkgver/UNLICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}