4 files changed, 51 insertions, 0 deletions

diff --git a/quich-git b/quich-git
deleted file mode 160000
-Subproject 29a0074041fc79656d5d578823574e5ce8ccdc2
diff --git a/quich-git/.SRCINFO b/quich-git/.SRCINFO
new file mode 100644
index 0000000..6b87de9
--- /dev/null
+++ b/quich-git/.SRCINFO
@@ -0,0 +1,14 @@
+pkgbase = quich-git
+        pkgdesc = calculator for terminal with numerous features
+        pkgver = 4.0.0.r3.ged2d2b7
+        pkgrel = 1
+        url = https://github.com/Usbac/quich
+        arch = x86_64
+        license = MIT
+        makedepends = git
+        provides = quich
+        conflicts = quich
+        source = git+https://github.com/Usbac/quich.git
+        sha256sums = SKIP
+
+pkgname = quich-git
diff --git a/quich-git/.gitignore b/quich-git/.gitignore
new file mode 100644
index 0000000..05c6d4d
--- /dev/null
+++ b/quich-git/.gitignore
@@ -0,0 +1,4 @@
+*
+!.gitignore
+!.SRCINFO
+!PKGBUILD
diff --git a/quich-git/PKGBUILD b/quich-git/PKGBUILD
new file mode 100644
index 0000000..c0ca232
--- /dev/null
+++ b/quich-git/PKGBUILD
@@ -0,0 +1,33 @@
+# Maintainer: Yigit Sever <yigit at yigitsever dot com>
+# Contributor: Caltlgin Stsodaat <contact@fossdaily.xyz>
+# Contributor: vscncls <lucaslou4@protonmail.com>
+
+_pkgname='quich'
+pkgname="${_pkgname}-git"
+pkgver=4.0.0.r3.ged2d2b7
+pkgrel=1
+pkgdesc='calculator for terminal with numerous features'
+arch=('x86_64')
+url='https://github.com/Usbac/quich'
+license=('MIT')
+makedepends=('git')
+provides=("${_pkgname}")
+conflicts=("${_pkgname}")
+source=("git+${url}.git")
+sha256sums=('SKIP')
+
+pkgver() {
+  git -C "${_pkgname}" describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+build() {
+  make -C "${_pkgname}" LDFLAGS="${LDFLAGS}"
+}
+
+package() {
+  cd "${_pkgname}"
+  install -D -m755 "${_pkgname}" -t "${pkgdir}/usr/bin"
+  install -D -m644 'README.md' -t "${pkgdir}/usr/share/doc/${_pkgname}"
+  install -D -m644 'LICENSE' -t "${pkgdir}/usr/share/licenses/${_pkgname}"
+  install -D -m644 'quich.1' -t "${pkgdir}/usr/share/man/man1"
+}