1 files changed, 31 insertions, 0 deletions

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 0000000..c1aba49
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,31 @@
+# Maintainer: Yigit Sever <yigit at yigitsever dot com>
+
+pkgname=tidy-viewer
+_pkgname=tv
+pkgver=0.0.13
+pkgrel=1
+pkgdesc="CLI csv pretty printer that uses column styling"
+arch=('x86_64')
+url="https://github.com/alexhallam/tv"
+license=('custom:unlicense')
+makedepends=('cargo')
+source=("${_pkgname}-${pkgver}.tar.gz::${url}/archive/${pkgver}.tar.gz")
+sha256sums=('9997675073806cb35286b3a499dbfb18ca14aa8bcba7fbda752e6b0cd05f623f')
+
+prepare() {
+        cd "$_pkgname-$pkgver"
+        cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
+}
+
+build() {
+        cd "$_pkgname-$pkgver"
+        export RUSTUP_TOOLCHAIN=stable
+        export CARGO_TARGET_DIR=target
+        cargo build --frozen --release
+}
+
+package() {
+        cd "$_pkgname-$pkgver"
+        install -Dm0755 -t "$pkgdir/usr/bin/" "target/release/$pkgname"
+  install -Dm644 "$srcdir/$_pkgname-$pkgver/UNLICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}