Use actual files instead of submodules

5 files changed, 95 insertions, 22 deletions

diff --git a/popcorntime-bin b/popcorntime-bin
deleted file mode 160000
-Subproject 9bc617fb6378bad53e07159c58b2d759d485e02
diff --git a/popcorntime-bin/.SRCINFO b/popcorntime-bin/.SRCINFO
new file mode 100644
index 0000000..8fd733f
--- /dev/null
+++ b/popcorntime-bin/.SRCINFO
@@ -0,0 +1,23 @@
+pkgbase = popcorntime-bin
+        pkgdesc = Stream free movies and TV shows from torrents
+        pkgver = 0.4.6
+        pkgrel = 1
+        url = https://github.com/popcorn-official/popcorn-desktop
+        arch = x86_64
+        license = GPL3
+        makedepends = unzip
+        depends = nss
+        depends = ttf-font
+        depends = libxss
+        depends = gtk3
+        provides = popcorntime
+        provides = popcorntime-ce
+        conflicts = popcorntime
+        conflicts = popcorntime-ce
+        options = !strip
+        source = https://github.com/popcorn-official/popcorn-desktop/releases/download/v0.4.6/Popcorn-Time-0.4.6-linux64.zip
+        source = popcorntime.desktop
+        sha256sums = 0fe15d2933b331a49b2da9a820e45a722b7d2d3224f92da0a31ce4a1296adad3
+        sha256sums = 4422f21e16176fda697ed0c8a6d1fb6f9dd7c4bc3f3694f9bcc19cbe66630334
+
+pkgname = popcorntime-bin
diff --git a/popcorntime-bin/.gitignore b/popcorntime-bin/.gitignore
new file mode 100644
index 0000000..a954168
--- /dev/null
+++ b/popcorntime-bin/.gitignore
@@ -0,0 +1,4 @@
+*.log
+Popcorn-Time-*-linux64.zip
+popcorntime-bin-*.pkg.tar.xz
+popcorntime-bin-*.pkg.tar.zst
diff --git a/popcorntime-bin/PKGBUILD b/popcorntime-bin/PKGBUILD
new file mode 100644
index 0000000..2d4cb7e
--- /dev/null
+++ b/popcorntime-bin/PKGBUILD
@@ -0,0 +1,59 @@
+# Maintainer: Yigit Sever <yigit at yigitsever dot com>
+# Contributor : Barfin
+# Contributor: Kostis Karantias <kkarantias [at] gmail [dot] com>
+# Contributor: Pieter Goetschalckx <3.14.e.ter [at] gmail [dot] com>
+# Contributor: Bastien Traverse <firstname at lastname dot email>
+# Contributor: Ricardo Funke <ricardo [at] gmail [dot] com>
+# Contributor: Attila Bukor <r1pp3rj4ck [at] w4it [dot] eu>
+# Contributor: Iwan Timmer <irtimmer [at] gmail [dot] com>
+# Contributor: Eric Engestrom <aur [at] engestrom [dot] ch>
+# Contributor: Ricardo Band <me [at] xengi [dot] de>
+# Contributor: Axilleas Pipinellis (aka axil42) <axilleas [at] archlinux [dot] info>
+# Contributor: UshakovVasilii <UshakovVasilii [at] yahoo [dot] com>
+# Contributor: Giulio Fidente <gfidente [at] gmail [dot] com>
+# Contributor: xantares <xantares09 [at] hotmail [dot] com>
+# Contributor: petterk <stifler3k [at] hotmail [dot] com>
+# Contributor: Stephan Springer <buzo+arch (at) Lini (dot) de>
+
+pkgname=popcorntime-bin
+_pkgname=popcorntime
+pkgver=0.4.6
+pkgrel=1
+pkgdesc="Stream free movies and TV shows from torrents"
+arch=('x86_64')
+url="https://github.com/popcorn-official/popcorn-desktop"
+license=('GPL3')
+depends=('nss' 'ttf-font' 'libxss' 'gtk3')
+makedepends=('unzip')
+provides=('popcorntime' 'popcorntime-ce')
+conflicts=('popcorntime' 'popcorntime-ce')
+options=('!strip')
+_zipfile="Popcorn-Time-${pkgver}-linux64.zip"
+source=("https://github.com/popcorn-official/popcorn-desktop/releases/download/v${pkgver}/$_zipfile"
+        "${_pkgname}.desktop" )
+sha256sums=('0fe15d2933b331a49b2da9a820e45a722b7d2d3224f92da0a31ce4a1296adad3'
+            '4422f21e16176fda697ed0c8a6d1fb6f9dd7c4bc3f3694f9bcc19cbe66630334')
+
+package() {
+  install -dm755 "${pkgdir}/usr/share/${_pkgname}"
+  install -dm755 "${pkgdir}/usr/bin"
+
+  # Link to program
+  ln -s "../share/${_pkgname}/Popcorn-Time" "${pkgdir}/usr/bin/${_pkgname}"
+
+  # Desktop file
+  install -Dm644 "${_pkgname}.desktop" "${pkgdir}/usr/share/applications/${_pkgname}.desktop"
+
+  # Icon
+  install -Dm644 "${srcdir}/src/app/images/icon.png" "${pkgdir}/usr/share/icons/hicolor/256x256/apps/${_pkgname}.png"
+
+  # Remove makepkg-created symlinks before copying content
+  rm "$_zipfile" "${_pkgname}.desktop"
+
+  # Copy complete content of source archive to /usr/share/${_pkgname}
+  cp -a "${srcdir}"/* "${pkgdir}/usr/share/${_pkgname}"
+
+  # Fix permissions
+  find "${pkgdir}/usr/share/${_pkgname}/" -perm 600 -exec chmod 644 '{}' \;
+  find "${pkgdir}/usr/share/${_pkgname}/" -perm 700 -exec chmod 755 '{}' \;
+}
diff --git a/popcorntime-bin/popcorntime.desktop b/popcorntime-bin/popcorntime.desktop
new file mode 100644
index 0000000..3b39b63
--- /dev/null
+++ b/popcorntime-bin/popcorntime.desktop
@@ -0,0 +1,9 @@
+[Desktop Entry]
+Name=Popcorn Time
+Comment=Watch Movies and TV Shows instantly
+Exec=popcorntime %U
+Icon=popcorntime
+MimeType=application/x-bittorrent;x-scheme-handler/magnet;
+StartupNotify=false
+Categories=AudioVideo;Video;Network;Player;P2P;
+Type=Application