Tracking adopted packages

- dvc
- flowy
- ouch{-bin, -git,}

2 files changed, 67 insertions, 0 deletions

diff --git a/ouch-git/.SRCINFO b/ouch-git/.SRCINFO
new file mode 100644
index 0000000..8f5b5e1
--- /dev/null
+++ b/ouch-git/.SRCINFO
@@ -0,0 +1,16 @@
+pkgbase = ouch-git
+        pkgdesc = Painless compression and decompression in the terminal (git version)
+        pkgver = r397.abf1d4e
+        pkgrel = 1
+        url = https://github.com/ouch-org/ouch/
+        arch = x86_64
+        license = MIT
+        makedepends = git
+        makedepends = cargo
+        provides = ouch
+        conflicts = ouch
+        conflicts = ouch-bin
+        source = ouch::git+https://github.com/ouch-org/ouch/
+        sha256sums = SKIP
+
+pkgname = ouch-git
diff --git a/ouch-git/PKGBUILD b/ouch-git/PKGBUILD
new file mode 100644
index 0000000..8e036ce
--- /dev/null
+++ b/ouch-git/PKGBUILD
@@ -0,0 +1,51 @@
+# Maintainer: Yigit Sever <yigit at yigitsever dot com>
+
+pkgname=ouch-git
+_pkgname=${pkgname%-git}
+pkgver=r397.abf1d4e
+pkgrel=1
+pkgdesc="Painless compression and decompression in the terminal (git version)"
+arch=('x86_64')
+url="https://github.com/ouch-org/ouch/"
+license=('MIT')
+makedepends=('git' 'cargo')
+provides=(${_pkgname})
+conflicts=(${_pkgname} ${_pkgname}-bin)
+source=("${_pkgname}::git+${url}")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd "$srcdir/${_pkgname}"
+  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+}
+
+prepare() {
+  cd "$srcdir/${_pkgname}"
+  cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
+}
+
+build() {
+  cd "$srcdir/${_pkgname}"
+  export RUSTUP_TOOLCHAIN=stable
+  export CARGO_TARGET_DIR=target
+  GEN_COMPLETIONS=1 cargo build --frozen --release --all-features
+}
+
+check() {
+  cd "$srcdir/${_pkgname}"
+  export RUSTUP_TOOLCHAIN=stable
+  cargo test --frozen --all-features
+}
+
+package() {
+  cd "$srcdir/${_pkgname}"
+  install -Dm0755 -t "$pkgdir/usr/bin/" "target/release/${_pkgname}"
+  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/${_pkgname}/LICENSE"
+
+  cd target/release/build/ouch-*/out/completions
+  sed -i "s/':output -- The resulting file. It's extensions can be used to specify the compression formats:_files'/\":output -- The resulting file. It's extensions can be used to specify the compression formats:_files\"/" _ouch
+
+  install -Dm0644 ${_pkgname}.bash "${pkgdir}/usr/share/bash-completion/completions/${_pkgname}"
+  install -Dm0644 ${_pkgname}.fish "${pkgdir}/usr/share/fish/vendor_completions.d/${_pkgname}.fish"
+  install -Dm0644 _${_pkgname} "${pkgdir}/usr/share/zsh/site-functions/_${_pkgname}"
+}