efm-langserver: adopted

1 files changed, 36 insertions, 0 deletions

diff --git a/efm-langserver/PKGBUILD b/efm-langserver/PKGBUILD
new file mode 100644
index 0000000..4bdc1ca
--- /dev/null
+++ b/efm-langserver/PKGBUILD
@@ -0,0 +1,36 @@
+# Maintainer: Yigit Sever <yigit at yigitsever dot com>
+# Contributor: Daniel M. Capella <polyzen@archlinux.org>
+# Contributor: dianlujitao <dianlujitao at gmail dot com>
+
+pkgname=efm-langserver
+pkgver=0.0.42
+pkgrel=1
+pkgdesc='General purpose Language Server'
+arch=('x86_64')
+url=https://github.com/mattn/efm-langserver
+license=('MIT')
+depends=('glibc')
+makedepends=('go')
+optdepends=('ctags: for "go to definition" requests')
+source=("$url/archive/v$pkgver/$pkgname-v$pkgver.tar.gz")
+sha256sums=('44ef0d86c7a1e9d64f205cbcb69ce242b6ca94d933963ef512747a6d03a553a3')
+
+build() {
+  cd $pkgname-$pkgver
+  export CGO_CPPFLAGS="$CPPFLAGS"
+  export CGO_CFLAGS="$CFLAGS"
+  export CGO_CXXFLAGS="$CXXFLAGS"
+  export CGO_LDFLAGS="$LDFLAGS"
+  export GOFLAGS="-buildmode=pie -trimpath -ldflags=-linkmode=external -mod=readonly -modcacherw"
+  go build .
+}
+
+check() {
+  cd $pkgname-$pkgver
+  go test -v ./...
+}
+
+package() {
+  cd $pkgname-$pkgver
+  install -Dt "$pkgdir"/usr/bin efm-langserver
+}