update to 2.3.0

1 files changed, 46 insertions, 0 deletions

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 0000000..ffd9a55
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,46 @@
+# Maintainer: zxp19821005 <zxp19821005 at 163 dot com>
+_pkgname=thorium
+pkgname="${_pkgname}-reader-bin"
+_appname=Thorium
+_fullname="${_appname}Reader"
+pkgver=2.3.0
+pkgrel=1
+pkgdesc="Cross-platform desktop reading app based on the Readium Desktop toolkit"
+arch=('x86_64')
+url="https://www.edrlab.org/software/thorium-reader/"
+_ghurl="https://github.com/edrlab/thorium-reader"
+license=('BSD')
+conflicts=("${pkgname%-bin}")
+provides=("${pkgname%-bin}=${pkgver}")
+depends=(
+    'bash'
+    'electron25'
+    'hicolor-icon-theme'
+)
+source=(
+    "${pkgname%-bin}-${pkgver}.deb::${_ghurl}/releases/download/v${pkgver}/EDRLab.${_fullname}_${pkgver}_amd64.deb"
+    "LICENSE::https://raw.githubusercontent.com/edrlab/thorium-reader/v${pkgver}/LICENSE"
+    "${pkgname%-bin}.sh"
+)
+sha256sums=('1007cd9083715d32427e4d39f8a4cac69cf428cfc4521950571dc2290a308f23'
+            'e95e504f42685015445b4a0a80dfdaa86e5b2b2c0e317bca2bcbb51330ec61e5'
+            'c6376c7762d524d36e463659d1b1a15870e8a57b1d8b257a8395072f04f97456')
+build() {
+    bsdtar -xf "${srcdir}/data.tar.xz"
+    sed -e "s|Name=${_appname}|Name=${_fullname}|g" \
+        -e "s|/opt/${_appname}/${_pkgname} %U|${pkgname%-bin}|g" \
+        -e "s|Icon=${_pkgname}|Icon=${pkgname%-bin}|g" \
+        -i "${srcdir}/usr/share/applications/${_pkgname}.desktop"
+}
+package() {
+    install -Dm755 "${srcdir}/${pkgname%-bin}.sh" "${pkgdir}/usr/bin/${pkgname%-bin}"
+    install -Dm755 "${srcdir}/opt/${_appname}/resources/app.asar" -t "${pkgdir}/usr/lib/${pkgname%-bin}"
+    install -Dm644 "${srcdir}/opt/${_appname}/resources/app.asar.unpacked/external-assets/lcp.node" \
+        -t "${pkgdir}/usr/lib/${pkgname%-bin}app.asar.unpacked/external-assets"
+    for _icons in 256x256 512x512 1024x1024;do
+        install -Dm644 "${srcdir}/usr/share/icons/hicolor/${_icons}/apps/${_pkgname}.png" \
+            "${pkgdir}/usr/share/icons/hicolor/${_icons}/apps/${pkgname%-bin}.png"
+    done
+    install -Dm644 "${srcdir}/usr/share/applications/${_pkgname}.desktop" "${pkgdir}/usr/share/applications/${pkgname%-bin}.desktop"
+    install -Dm644 "${srcdir}/LICENSE" -t "${pkgdir}/usr/share/licenses/${pkgname}"
+}
\ No newline at end of file