From 31d147b20c67d95a9e306d0749200bf964ac42af Mon Sep 17 00:00:00 2001
From: Yigit Sever
Date: Fri, 29 Oct 2021 01:30:24 +0300
Subject: Use actual files instead of submodules

---
 metadata-cleaner/PKGBUILD | 29 +++++++++++++++++++++++++++++
 1 file changed, 29 insertions(+)
 create mode 100644 metadata-cleaner/PKGBUILD

(limited to 'metadata-cleaner/PKGBUILD')

diff --git a/metadata-cleaner/PKGBUILD b/metadata-cleaner/PKGBUILD
new file mode 100644
index 0000000..f1edfa0
--- /dev/null
+++ b/metadata-cleaner/PKGBUILD
@@ -0,0 +1,29 @@
+# Maintainer: Yigit Sever <yigit at yigitsever dot com>
+# Contributor: Mark Wagie <mark dot wagie at tutanota dot com>
+# Contributor: lxsycht <lux@systemli.org>
+
+pkgname=metadata-cleaner
+pkgver=2.0.1
+pkgrel=1
+pkgdesc="Python GTK application to view and clean metadata in files, using mat2"
+arch=('x86_64')
+url="https://gitlab.com/rmnvgr/metadata-cleaner"
+license=('GPL3')
+depends=('gtk4' 'libadwaita' 'mat2' 'python-gobject')
+makedepends=('itstool' 'meson')
+checkdepends=('appstream' 'mypy' 'python-pycodestyle' 'python-pydocstyle' 'reuse')
+source=("${pkgname}-${pkgver}.tar.gz::${url}/-/archive/v$pkgver/$pkgname-v$pkgver.tar.gz")
+sha256sums=('9a52c06680729cfc4de4a7bc24e9c2ae19930892b4130a57c4fa7db1d496709c')
+
+build() {
+  arch-meson "$pkgname-v$pkgver" build
+  meson compile -C build
+}
+
+check() {
+  meson test -C build --print-errorlogs
+}
+
+package() {
+  meson install -C build --destdir "$pkgdir"
+}
-- 
cgit v1.2.3-70-g09d2