From 31d147b20c67d95a9e306d0749200bf964ac42af Mon Sep 17 00:00:00 2001
From: Yigit Sever
Date: Fri, 29 Oct 2021 01:30:24 +0300
Subject: Use actual files instead of submodules

---
 elementary-icon-theme-git          |  1 -
 elementary-icon-theme-git/.SRCINFO | 20 ++++++++++++++++
 elementary-icon-theme-git/PKGBUILD | 47 ++++++++++++++++++++++++++++++++++++++
 3 files changed, 67 insertions(+), 1 deletion(-)
 delete mode 160000 elementary-icon-theme-git
 create mode 100644 elementary-icon-theme-git/.SRCINFO
 create mode 100644 elementary-icon-theme-git/PKGBUILD

(limited to 'elementary-icon-theme-git')

diff --git a/elementary-icon-theme-git b/elementary-icon-theme-git
deleted file mode 160000
index 6612d81..0000000
--- a/elementary-icon-theme-git
+++ /dev/null
@@ -1 +0,0 @@
-Subproject commit 6612d810eb26a8cbcc9be16219f61182cd201f32
diff --git a/elementary-icon-theme-git/.SRCINFO b/elementary-icon-theme-git/.SRCINFO
new file mode 100644
index 0000000..ab34fbd
--- /dev/null
+++ b/elementary-icon-theme-git/.SRCINFO
@@ -0,0 +1,20 @@
+pkgbase = elementary-icon-theme-git
+	pkgdesc = Named, vector icons for elementary OS
+	pkgver = 6.0.0.r4.g9c8e5b0f
+	pkgrel = 1
+	url = https://github.com/elementary/icons
+	arch = any
+	groups = pantheon-unstable
+	license = GPL3
+	makedepends = git
+	makedepends = meson
+	makedepends = inkscape
+	makedepends = xorg-xcursorgen
+	depends = hicolor-icon-theme
+	provides = elementary-icon-theme
+	conflicts = elementary-icon-theme
+	options = !emptydirs
+	source = elementary-icon-theme::git+https://github.com/elementary/icons.git
+	sha256sums = SKIP
+
+pkgname = elementary-icon-theme-git
diff --git a/elementary-icon-theme-git/PKGBUILD b/elementary-icon-theme-git/PKGBUILD
new file mode 100644
index 0000000..bd99ec9
--- /dev/null
+++ b/elementary-icon-theme-git/PKGBUILD
@@ -0,0 +1,47 @@
+# Maintainer: Yigit Sever <yigit at yigitsever dot com>
+# Contributor: Dimitris Kiziridis <ragouel at outlook dot com>
+# Contributor: Maxime Gauduin <alucryd@archlinux.org>
+
+pkgname=elementary-icon-theme-git
+pkgver=6.0.0.r4.g9c8e5b0f
+pkgrel=1
+pkgdesc='Named, vector icons for elementary OS'
+arch=('any')
+url='https://github.com/elementary/icons'
+license=('GPL3')
+groups=('pantheon-unstable')
+depends=('hicolor-icon-theme')
+makedepends=('git' 'meson' 'inkscape' 'xorg-xcursorgen')
+provides=('elementary-icon-theme')
+conflicts=('elementary-icon-theme')
+options=('!emptydirs')
+source=("elementary-icon-theme::git+${url}.git")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd "${srcdir}/elementary-icon-theme"
+  # https://wiki.archlinux.org/title/VCS_package_guidelines#Git
+  # Upstream has annotated tags
+  git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+prepare() {
+  cd "${srcdir}/elementary-icon-theme"
+  if [[ -d build ]]; then
+    rm -rf build
+  fi
+  mkdir build
+}
+
+build() {
+  cd "${srcdir}/elementary-icon-theme/build"
+  arch-meson ../
+  ninja
+}
+
+package() {
+  cd "${srcdir}/elementary-icon-theme/build"
+  DESTDIR="${pkgdir}" ninja install
+  rm "${pkgdir}"/.VolumeIcon*
+}
+# vim: ts=2 sw=2 et:
-- 
cgit v1.2.3-70-g09d2