1 files changed, 37 insertions, 0 deletions

diff --git a/tex-fmt/PKGBUILD b/tex-fmt/PKGBUILD
new file mode 100644
index 0000000..5694eee
--- /dev/null
+++ b/tex-fmt/PKGBUILD
@@ -0,0 +1,37 @@
+# Maintainer: Yigit Sever <yigit at yigitsever dot com>
+
+pkgname=tex-fmt
+pkgver=0.4.7
+pkgrel=1
+pkgdesc="An extremely fast LaTeX formatter written in Rust"
+arch=('x86_64')
+url="https://github.com/WGUNDERWOOD/tex-fmt"
+license=('MIT')
+makedepends=(cargo)
+source=("${pkgname}-${pkgver}.tar.gz::${url}/archive/refs/tags/v${pkgver}.tar.gz")
+sha256sums=('3259a5ee9211753787e894c10313541108149285e7eba27f8281886bb14b5c79')
+
+prepare() {
+  cd "$srcdir/$pkgname-$pkgver"
+  export RUSTUP_TOOLCHAIN=stable
+  cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
+}
+
+build() {
+        cd "$srcdir/$pkgname-$pkgver"
+  export RUSTUP_TOOLCHAIN=stable
+  export CARGO_TARGET_DIR=target
+  cargo build --frozen --release --all-features
+}
+
+check() {
+  cd "$srcdir/$pkgname-$pkgver"
+  export RUSTUP_TOOLCHAIN=stable
+  cargo test --frozen --all-features
+}
+
+package() {
+  cd "$srcdir/$pkgname-$pkgver"
+  install -Dm0755 -t "$pkgdir/usr/bin/" "target/release/$pkgname"
+  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}