3 files changed, 51 insertions, 0 deletions

diff --git a/nmly-git/.SRCINFO b/nmly-git/.SRCINFO
new file mode 100644
index 0000000..c0511f1
--- /dev/null
+++ b/nmly-git/.SRCINFO
@@ -0,0 +1,15 @@
+pkgbase = nmly-git
+        pkgdesc = Bulk rename utility with useful functions
+        pkgver = 1.1.1.r11.gbdb2577
+        pkgrel = 1
+        url = https://github.com/Usbac/nmly
+        arch = x86_64
+        license = MIT
+        makedepends = git
+        provides = nmly
+        conflicts = nmly
+        source = git+https://github.com/Usbac/nmly.git
+        sha256sums = SKIP
+
+pkgname = nmly-git
+
diff --git a/nmly-git/.gitignore b/nmly-git/.gitignore
new file mode 100644
index 0000000..05c6d4d
--- /dev/null
+++ b/nmly-git/.gitignore
@@ -0,0 +1,4 @@
+*
+!.gitignore
+!.SRCINFO
+!PKGBUILD
diff --git a/nmly-git/PKGBUILD b/nmly-git/PKGBUILD
new file mode 100644
index 0000000..32ee93e
--- /dev/null
+++ b/nmly-git/PKGBUILD
@@ -0,0 +1,32 @@
+# Maintainer: Caltlgin Stsodaat <[email protected]>
+
+_pkgname='nmly'
+pkgname="${_pkgname}-git"
+pkgver=1.1.1.r11.gbdb2577
+pkgrel=1
+pkgdesc='Bulk rename utility with useful functions'
+arch=('x86_64')
+url='https://github.com/Usbac/nmly'
+license=('MIT')
+makedepends=('git')
+provides=("${_pkgname}")
+conflicts=("${_pkgname}")
+source=("git+${url}.git")
+sha256sums=('SKIP')
+
+pkgver() {
+  git -C "${_pkgname}" describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+build() {
+  make -C "${_pkgname}" LDFLAGS="${LDFLAGS}"
+}
+
+package() {
+  cd "${_pkgname}"
+  install -Dvm755 "${_pkgname}" -t "${pkgdir}/usr/bin"
+  install -Dvm644 'README.md' -t "${pkgdir}/usr/share/doc/${_pkgname}"
+  install -Dvm644 'LICENSE' -t "${pkgdir}/usr/share/licenses/${_pkgname}"
+}
+
+# vim: ts=2 sw=2 et: