1 files changed, 37 insertions, 0 deletions

diff --git a/dnsx/PKGBUILD b/dnsx/PKGBUILD
new file mode 100644
index 0000000..c9de2bb
--- /dev/null
+++ b/dnsx/PKGBUILD
@@ -0,0 +1,37 @@
+# Maintainer: Yigit Sever <yigit at yigitsever dot com>
+# Contributor: Caltlgin Stsodaat <contact@fossdaily.xyz>
+
+pkgname='dnsx'
+pkgver=1.2.2
+pkgrel=1
+pkgdesc='Fast and multi-purpose DNS toolkit'
+arch=('x86_64')
+url='https://github.com/projectdiscovery/dnsx'
+license=('MIT')
+makedepends=('go')
+provides=("${pkgname}")
+source=("${pkgname}-${pkgver}.tar.gz::${url}/archive/v${pkgver}.tar.gz")
+sha256sums=('fa9ee47996315b0d5b293fcf9263ac46ee69fc691ee024a400ebcd2e48f015e5')
+
+prepare() {
+  export GOPATH="${srcdir}/gopath"
+  go clean -modcache
+}
+
+build() {
+  export CGO_CPPFLAGS="${CPPFLAGS}"
+  export CGO_CFLAGS="${CFLAGS}"
+  export CGO_CXXFLAGS="${CXXFLAGS}"
+  export CGO_LDFLAGS="${LDFLAGS}"
+  export GOFLAGS="-buildmode=pie -trimpath -ldflags=-linkmode=external -mod=readonly -modcacherw"
+
+  cd "${pkgname}-${pkgver}/cmd/${pkgname}"
+  go build -v -o "${pkgname}" .
+}
+
+package() {
+  cd "${pkgname}-${pkgver}"
+  install -Dvm755 "cmd/${pkgname}/${pkgname}" -t "${pkgdir}/usr/bin"
+  install -Dvm644 'README.md' -t "${pkgdir}/usr/share/doc/${pkgname}"
+  install -Dvm644 'LICENSE.md' "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+}