1 files changed, 33 insertions, 0 deletions

diff --git a/cvemap/PKGBUILD b/cvemap/PKGBUILD
new file mode 100644
index 0000000..9f03f14
--- /dev/null
+++ b/cvemap/PKGBUILD
@@ -0,0 +1,33 @@
+# Maintainer: Yigit Sever <yigit at yigitsever dot com>
+
+pkgname=cvemap
+pkgver=0.0.7
+pkgrel=1
+pkgdesc="Navigate the CVE jungle with ease"
+arch=('x86_64')
+url="https://github.com/projectdiscovery/cvemap"
+license=('MIT')
+makedepends=('go')
+source=("${pkgname}-${pkgver}.tar.gz::${url}/archive/refs/tags/v${pkgver}.tar.gz")
+sha256sums=('4648b800c596e388a22922a04849f58f04bb5f73630cd8006c2756b3751b889b')
+
+prepare() {
+        cd "${pkgname}-${pkgver}"
+        mkdir -p build/
+}
+
+build() {
+        cd "${pkgname}-${pkgver}"
+        export CGO_CPPFLAGS="${CPPFLAGS}"
+        export CGO_CFLAGS="${CFLAGS}"
+        export CGO_CXXFLAGS="${CXXFLAGS}"
+        export CGO_LDFLAGS="${LDFLAGS}"
+        export GOFLAGS="-buildmode=pie -trimpath -ldflags=-linkmode=external -mod=readonly -modcacherw"
+        go build -o build ./cmd/...
+}
+
+package() {
+        cd "${pkgname}-${pkgver}"
+        install -Dm755 build/$pkgname "$pkgdir"/usr/bin/$pkgname
+        install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}