summaryrefslogtreecommitdiffstats
diff options
context:
space:
mode:
Diffstat
-rw-r--r--dvc/.SRCINFO49
-rw-r--r--dvc/PKGBUILD40
-rw-r--r--flowy/.SRCINFO13
-rw-r--r--flowy/PKGBUILD30
-rw-r--r--ouch-bin/.SRCINFO16
-rw-r--r--ouch-bin/PKGBUILD21
-rw-r--r--ouch-git/.SRCINFO16
-rw-r--r--ouch-git/PKGBUILD51
-rw-r--r--ouch/.SRCINFO14
-rw-r--r--ouch/PKGBUILD45
10 files changed, 295 insertions, 0 deletions
diff --git a/dvc/.SRCINFO b/dvc/.SRCINFO
new file mode 100644
index 0000000..955e60f
--- /dev/null
+++ b/dvc/.SRCINFO
@@ -0,0 +1,49 @@
1pkgbase = dvc
2 pkgdesc = Open-source version control system for data science projects
3 pkgver = 2.8.3
4 pkgrel = 1
5 url = https://github.com/iterative/dvc
6 arch = any
7 license = Apache
8 makedepends = git
9 depends = python
10 depends = python-appdirs
11 depends = python-colorama
12 depends = python-configobj
13 depends = python-distro
14 depends = python-flufl-lock
15 depends = python-funcy
16 depends = python-gitdb
17 depends = python-gitpython
18 depends = python-humanize
19 depends = python-inflect
20 depends = python-packaging
21 depends = python-pathspec
22 depends = python-ply
23 depends = python-pyasn1
24 depends = python-yaml
25 depends = python-requests
26 depends = python-ruamel-yaml
27 depends = python-setuptools
28 depends = python-shortuuid
29 depends = python-tqdm
30 depends = python-treelib
31 depends = python-voluptuous
32 depends = python-zc.lockfile
33 depends = python-nanotime
34 depends = python-grandalf
35 depends = python-ntfs
36 depends = python-shtab
37 depends = python-pygtrie
38 optdepends = python-google-cloud-storage: support for Google Cloud
39 optdepends = python-google-api-python-client: support for GDrive
40 optdepends = python-pydrive: support for GDrive
41 optdepends = python-boto3: support for AWS S3 remote
42 optdepends = python-paramiko: support for SSH remote
43 optdepends = python-azure-storage: support for Azure remote
44 optdepends = python-oss2: support for Aliyun Object Storage Service (OSS)
45 optdepends = python-pyarrow: support for HDFS remote
46 source = git+https://github.com/iterative/dvc/#commit=4175f9ffa4948157436283bef11153a7233e90ca
47 sha256sums = SKIP
48
49pkgname = dvc
diff --git a/dvc/PKGBUILD b/dvc/PKGBUILD
new file mode 100644
index 0000000..baa792d
--- /dev/null
+++ b/dvc/PKGBUILD
@@ -0,0 +1,40 @@
1# Maintainer: Stefan Husmann <stefan-husmann@t-online.de>
2# Contributor: Lex Black <autumn-wind@web.de>
3# Contributor: Mr. Outis <mroutis@protonmail.com>
4
5pkgname=dvc
6pkgver=2.8.3
7pkgrel=1
8pkgdesc="Open-source version control system for data science projects"
9arch=('any')
10license=('Apache')
11url="https://github.com/iterative/${pkgname}"
12depends=('python' 'python-appdirs' 'python-colorama' 'python-configobj'
13 'python-distro' 'python-flufl-lock' 'python-funcy' 'python-gitdb'
14 'python-gitpython' 'python-humanize' 'python-inflect'
15 'python-packaging' 'python-pathspec' 'python-ply' 'python-pyasn1'
16 'python-yaml' 'python-requests' 'python-ruamel-yaml'
17 'python-setuptools' 'python-shortuuid' 'python-tqdm'
18 'python-treelib' 'python-voluptuous' 'python-zc.lockfile'
19 'python-nanotime' 'python-grandalf' 'python-ntfs' 'python-shtab'
20 'python-pygtrie'
21)
22optdepends=('python-google-cloud-storage: support for Google Cloud'
23 'python-google-api-python-client: support for GDrive'
24 'python-pydrive: support for GDrive'
25 'python-boto3: support for AWS S3 remote'
26 'python-paramiko: support for SSH remote'
27 'python-azure-storage: support for Azure remote'
28 'python-oss2: support for Aliyun Object Storage Service (OSS)'
29 'python-pyarrow: support for HDFS remote'
30 )
31makedepends=('git')
32
33source=("git+${url}/#commit=4175f9ffa4948157436283bef11153a7233e90ca")
34sha256sums=('SKIP')
35
36package() {
37 cd ${pkgname}
38 python setup.py install --prefix=/usr --root="${pkgdir}" --optimize=1
39}
40
diff --git a/flowy/.SRCINFO b/flowy/.SRCINFO
new file mode 100644
index 0000000..a6a3064
--- /dev/null
+++ b/flowy/.SRCINFO
@@ -0,0 +1,13 @@
1pkgbase = flowy
2 pkgdesc = A lean, privacy-preserving dynamic wallpaper changer written in Rust
3 pkgver = 0.4.0
4 pkgrel = 1
5 url = https://github.com/vineetred/flowy
6 arch = x86_64
7 license = GPL
8 makedepends = cargo
9 conflicts = flowy-git
10 source = flowy-0.4.0.tar.gz::https://github.com/vineetred/flowy/archive/0.4.0.tar.gz
11 sha256sums = a0c4b98140df25f4c0a6d129dd9f5394c930c304c93527b5a7c664d649b9d677
12
13pkgname = flowy
diff --git a/flowy/PKGBUILD b/flowy/PKGBUILD
new file mode 100644
index 0000000..de48302
--- /dev/null
+++ b/flowy/PKGBUILD
@@ -0,0 +1,30 @@
1# Maintainer: Yigit Sever <yigit at yigitsever dot com>
2
3pkgname=flowy
4pkgver=0.4.0
5pkgrel=1
6pkgdesc="A lean, privacy-preserving dynamic wallpaper changer written in Rust"
7arch=('x86_64')
8url="https://github.com/vineetred/flowy"
9license=('GPL')
10makedepends=('cargo')
11conflicts=("${pkgname}-git")
12source=("${pkgname}-${pkgver}.tar.gz::${url}/archive/${pkgver}.tar.gz")
13sha256sums=('a0c4b98140df25f4c0a6d129dd9f5394c930c304c93527b5a7c664d649b9d677')
14
15prepare() {
16 cd "$pkgname-$pkgver"
17 cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
18}
19
20build() {
21 cd "$pkgname-$pkgver"
22 export RUSTUP_TOOLCHAIN=stable
23 export CARGO_TARGET_DIR=target
24 cargo build --frozen --release --all-features
25}
26
27package() {
28 cd "$pkgname-$pkgver"
29 install -Dm0755 -t "$pkgdir/usr/bin/" "target/release/$pkgname"
30}
diff --git a/ouch-bin/.SRCINFO b/ouch-bin/.SRCINFO
new file mode 100644
index 0000000..6247c1d
--- /dev/null
+++ b/ouch-bin/.SRCINFO
@@ -0,0 +1,16 @@
1pkgbase = ouch-bin
2 pkgdesc = Painless compression and decompression in the terminal (binary release)
3 pkgver = 0.3.1
4 pkgrel = 1
5 url = https://github.com/ouch-org/ouch
6 arch = x86_64
7 license = MIT
8 provides = ouch
9 conflicts = ouch
10 conflicts = ouch-git
11 source = ouch::https://github.com/ouch-org/ouch/releases/download/0.3.1/ouch-x86_64-linux-musl
12 source = LICENSE::https://raw.githubusercontent.com/ouch-org/ouch/master/LICENSE
13 sha256sums = 48843b18aee48273e60456267c408163d51df046ad79a6cdd99c75c45cb79afe
14 sha256sums = f082ccc8a66b3fdbeb6d53d5fe084934fc6f480a9d1d9243d2c5d9e45ec76938
15
16pkgname = ouch-bin
diff --git a/ouch-bin/PKGBUILD b/ouch-bin/PKGBUILD
new file mode 100644
index 0000000..9bc3dfd
--- /dev/null
+++ b/ouch-bin/PKGBUILD
@@ -0,0 +1,21 @@
1# Maintainer: Yigit Sever <yigit at yigitsever dot com>
2
3pkgname=ouch-bin
4_pkgname=${pkgname%-bin}
5pkgver=0.3.1
6pkgrel=1
7pkgdesc="Painless compression and decompression in the terminal (binary release)"
8arch=('x86_64')
9url="https://github.com/ouch-org/ouch"
10license=('MIT')
11provides=(${_pkgname})
12conflicts=(${_pkgname} ${_pkgname}-git)
13source=("${_pkgname}::${url}/releases/download/${pkgver}/ouch-x86_64-linux-musl"
14 "LICENSE::https://raw.githubusercontent.com/ouch-org/ouch/master/LICENSE")
15sha256sums=('48843b18aee48273e60456267c408163d51df046ad79a6cdd99c75c45cb79afe'
16 'f082ccc8a66b3fdbeb6d53d5fe084934fc6f480a9d1d9243d2c5d9e45ec76938')
17
18package() {
19 install -Dm644 LICENSE "$pkgdir/usr/share/licenses/${_pkgname}/LICENSE"
20 install -Dvm755 "${_pkgname}" -t "${pkgdir}/usr/bin"
21}
diff --git a/ouch-git/.SRCINFO b/ouch-git/.SRCINFO
new file mode 100644
index 0000000..8f5b5e1
--- /dev/null
+++ b/ouch-git/.SRCINFO
@@ -0,0 +1,16 @@
1pkgbase = ouch-git
2 pkgdesc = Painless compression and decompression in the terminal (git version)
3 pkgver = r397.abf1d4e
4 pkgrel = 1
5 url = https://github.com/ouch-org/ouch/
6 arch = x86_64
7 license = MIT
8 makedepends = git
9 makedepends = cargo
10 provides = ouch
11 conflicts = ouch
12 conflicts = ouch-bin
13 source = ouch::git+https://github.com/ouch-org/ouch/
14 sha256sums = SKIP
15
16pkgname = ouch-git
diff --git a/ouch-git/PKGBUILD b/ouch-git/PKGBUILD
new file mode 100644
index 0000000..8e036ce
--- /dev/null
+++ b/ouch-git/PKGBUILD
@@ -0,0 +1,51 @@
1# Maintainer: Yigit Sever <yigit at yigitsever dot com>
2
3pkgname=ouch-git
4_pkgname=${pkgname%-git}
5pkgver=r397.abf1d4e
6pkgrel=1
7pkgdesc="Painless compression and decompression in the terminal (git version)"
8arch=('x86_64')
9url="https://github.com/ouch-org/ouch/"
10license=('MIT')
11makedepends=('git' 'cargo')
12provides=(${_pkgname})
13conflicts=(${_pkgname} ${_pkgname}-bin)
14source=("${_pkgname}::git+${url}")
15sha256sums=('SKIP')
16
17pkgver() {
18 cd "$srcdir/${_pkgname}"
19 printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
20}
21
22prepare() {
23 cd "$srcdir/${_pkgname}"
24 cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
25}
26
27build() {
28 cd "$srcdir/${_pkgname}"
29 export RUSTUP_TOOLCHAIN=stable
30 export CARGO_TARGET_DIR=target
31 GEN_COMPLETIONS=1 cargo build --frozen --release --all-features
32}
33
34check() {
35 cd "$srcdir/${_pkgname}"
36 export RUSTUP_TOOLCHAIN=stable
37 cargo test --frozen --all-features
38}
39
40package() {
41 cd "$srcdir/${_pkgname}"
42 install -Dm0755 -t "$pkgdir/usr/bin/" "target/release/${_pkgname}"
43 install -Dm644 LICENSE "$pkgdir/usr/share/licenses/${_pkgname}/LICENSE"
44
45 cd target/release/build/ouch-*/out/completions
46 sed -i "s/':output -- The resulting file. It's extensions can be used to specify the compression formats:_files'/\":output -- The resulting file. It's extensions can be used to specify the compression formats:_files\"/" _ouch
47
48 install -Dm0644 ${_pkgname}.bash "${pkgdir}/usr/share/bash-completion/completions/${_pkgname}"
49 install -Dm0644 ${_pkgname}.fish "${pkgdir}/usr/share/fish/vendor_completions.d/${_pkgname}.fish"
50 install -Dm0644 _${_pkgname} "${pkgdir}/usr/share/zsh/site-functions/_${_pkgname}"
51}
diff --git a/ouch/.SRCINFO b/ouch/.SRCINFO
new file mode 100644
index 0000000..37e0570
--- /dev/null
+++ b/ouch/.SRCINFO
@@ -0,0 +1,14 @@
1pkgbase = ouch
2 pkgdesc = Painless compression and decompression in the terminal
3 pkgver = 0.3.1
4 pkgrel = 3
5 url = https://github.com/ouch-org/ouch
6 arch = x86_64
7 license = MIT
8 makedepends = cargo
9 conflicts = ouch-git
10 conflicts = ouch-bin
11 source = ouch-0.3.1.tar.gz::https://github.com/ouch-org/ouch/archive/0.3.1.tar.gz
12 sha256sums = 269abaf5ac2f80da3796dbf5e73419c1b64104d1295f3ff57965141f079e6f6d
13
14pkgname = ouch
diff --git a/ouch/PKGBUILD b/ouch/PKGBUILD
new file mode 100644
index 0000000..5d3f5fa
--- /dev/null
+++ b/ouch/PKGBUILD
@@ -0,0 +1,45 @@
1# Maintainer: Yigit Sever <yigit at yigitsever dot com>
2
3pkgname=ouch
4pkgver=0.3.1
5pkgrel=3
6pkgdesc="Painless compression and decompression in the terminal"
7arch=('x86_64')
8url="https://github.com/ouch-org/ouch"
9license=('MIT')
10makedepends=('cargo')
11conflicts=(${pkgname}-git ${pkgname}-bin)
12source=("${pkgname}-${pkgver}.tar.gz::${url}/archive/${pkgver}.tar.gz")
13sha256sums=('269abaf5ac2f80da3796dbf5e73419c1b64104d1295f3ff57965141f079e6f6d')
14
15prepare() {
16 cd "$srcdir/$pkgname-$pkgver"
17 cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
18}
19
20build() {
21 cd "$srcdir/$pkgname-$pkgver"
22 export RUSTUP_TOOLCHAIN=stable
23 export CARGO_TARGET_DIR=target
24 GEN_COMPLETIONS=1 cargo build --frozen --release --all-features
25}
26
27check() {
28 cd "$srcdir/$pkgname-$pkgver"
29 export RUSTUP_TOOLCHAIN=stable
30 cargo test --frozen --all-features
31}
32
33package() {
34 cd "$srcdir/$pkgname-$pkgver"
35
36 install -Dm0755 -t "$pkgdir/usr/bin/" "target/release/$pkgname"
37 install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
38
39 cd target/release/build/ouch-*/out/completions
40 sed -i "s/':output -- The resulting file. It's extensions can be used to specify the compression formats:_files'/\":output -- The resulting file. It's extensions can be used to specify the compression formats:_files\"/" _ouch
41
42 install -Dm0644 ${pkgname}.bash "${pkgdir}/usr/share/bash-completion/completions/${pkgname}"
43 install -Dm0644 ${pkgname}.fish "${pkgdir}/usr/share/fish/vendor_completions.d/${pkgname}.fish"
44 install -Dm0644 _${pkgname} "${pkgdir}/usr/share/zsh/site-functions/_${pkgname}"
45}
generated by cgit v1.2.3-70-g09d2 (git 2.46.0) at 2024-11-22 00:48:49 +0000